Hikkake Pattern by Daniel Chesler
The hikkake pattern, or hikkake, is a technical analysis pattern used for determining market turning-points and continuations. It is a simple pattern that can be observed in market price data, using traditional bar charts, point and figure charts, or Japanese candlestick charts. The pattern does not belong to the collection of traditional candlestick chart patterns.
Though some have referred to the hikkake pattern as an “inside day false breakout” or a “fakey pattern”, these are deviations from the original name given to the pattern by Daniel L. Chesler, CMT and are not popularly used to describe the pattern. For example, the name “hikkake pattern” has been chosen over “inside day false breakout” or “fakey pattern” by the majority of book authors who have covered the subject.
(description from Wikipedia).
// The Hikkake Pattern, by Daniel Chesler, CMT
// The 'Fakey' entry
// coded by Violet
// 28-11-2017
//
// For an explanation of the pattern, consult this webpage:
// http://www.esignallearning.com/education/marketmaster/archive/2012/archive_index.aspx?date=041312
// Also read this interesting report:
// https://oxfordstrat.com/trading-strategies/hikkake-pattern/
//
// Use it for market timing, but always in conjunction with position sizing and a sensible stoploss !
// because like every other technique this one may fail
InsideBar = high[1] < high[2] and low[1] > low[2]
FakeBullBar = low < low[1] and high < high[1]
FakeBearBar = low > low[1] and high > high[1]
// Long Setup
if InsideBar and FakeBullBar then
HikkakeBull = 1 // flag for a potential bullish setup
InsideBullBarHigh = high[1] // set the high of the insidebar
InsideBarNumber = barindex - 1
HikkakeBarNumber = barindex // signal bar, bar number of completed Hikkake setup
endif
if HikkakeBull then
WithinTimeLimit = (barindex - HikkakeBarNumber) <= 3
if close > InsideBullBarHigh and WithinTimeLimit then
//setup confirmed if price closes higher then InsideBullBarHigh within 3 bars after pattern completion
drawarrowup(barindex,low-range/8) coloured(0,255,125)
drawsegment(InsidebarNumber,InsideBullBarHigh+ticksize,barindex,InsideBullBarHigh+ticksize)
drawtext("▴",barindex,InsideBullBarHigh-ticksize, dialog,bold,20)
HikkakeBull = 0 // reset pattern detection flag
endif
endif
// Short/Sell setup
if InsideBar and FakeBearBar then
HikkakeBear = 1 // flag for a potential bearish setup
InsideBearBarLow = low[1] // set the low of the insidebar
InsideBearBarNumber = barindex - 1
HikkakeBearBarNumber = barindex // signal bar, bar number of completed Hikkake setup on third bar
endif
if HikkakeBear then
WithinTimeLimit = (barindex - HikkakeBearBarNumber) <= 3
if close < InsideBearBarLow and WithinTimeLimit then
//setup confirmed if price closes lower then InsideBearBarow within 3 bars after pattern completion
drawarrowdown(barindex,high+range/8) coloured(255,0,0)
drawsegment(InsideBearBarNumber,InsideBearBarLow-ticksize,barindex,InsideBearBarLow-ticksize)
drawtext("▾",barindex,InsideBearBarLow - ticksize, dialog,bold,20)
HikkakeBear = 0 // reset pattern detection flag
endif
endif
//drawcandle(open, high, low,close)
return
Comments
You must be logged in to post a comment.
Hi Gregg, TP and SL? There are no variables by those names. The signal appears/disappears because the bar/candle you are in at that moment has not yet come to its full time conclusion. Do not use it for trading purposes until the candle with the red or green arrow has run its full course , and a new candle has begun. Greetz
thanks
Violet, congratulations, I checked your code in different time frames, and in many situations I found 50% of useful results, which are really few, but an indicator is very reliable and excellent results and I can tell you how and where to use it . But I need to know first, how to compensate, how you can make an alert, acoustic, visual, or anything else that when you form the arrow give me a signal. I await, thank you
Thanks for this simple code. How would you readjust it to only show reversals? Chesler adds following requirements to it: Take the standard hikkake pattern and and apply the following set of requirements to the bard immediately preceding the "inside" bar: 1) The bar must close at the top of its range (for top reversals) or the low of its range (for bottom reversals) 2) The bar's range must be less than the range of the previous bar. Thanks.
I tried it and gives good directions, although some short, on the daily and 4 hours, I’m testing the 10 minutes of which appear some departures, but you can check with others. Here I wanted to ask, it is possible to appear a new arrow to put an acoustic signal or to intervene a window like ProOrder Auto Trading? Do something that alerts you? Thank you .
I tried it and gives good directions, although some short, on the daily and 4 hours, I'm testing the 10 minutes of which appear some departures, but you can check with others. Here I wanted to ask, it is possible to appear a new arrow to put an acoustic signal or to intervene a window like ProOrder Auto Trading? Do something that alerts you? Thank you .
L'ho provato e dà buone indicazioni , anche se alcune brevi , sul giornaliero e il 4 ore , lo sto testando sul 10 minuti di cui compaiono alcune flase partenze , però si può controllare con altro . Ecco volevo chiedere , è possibile al comparire di una freccia nuova mettere un segnale acustico o far intervenire una finestra tipo ProOrder Auto Trading ? Fare qualcosa che avvisi ? Grazie .
Thanks great job !