Pocket pivots based on Chris Kacher / Gil Morales.

Highest volume of last ten days, higher than any down day.

Stronger the trend the bettter.

Shows accumilation / re accumilation on up days / waves.

I change it to Histogram to get the nice blue bars.

Credit to who wrote this, I was given it over Twitter,

Cheers,

Dale.

// ----------------------------------

// The Pocket Pivot Screener

//

// ver 0.1

//     0.2 - using the max volume of a down day in the past 10 days

//

// ----------------------------------



// Basic criteria



minPrice = 0.05

minVol = 10000

daysToConfirmUpTrend = 50



// Only scan leading stocks above minimal price and 40 day moving average of Volume is above 500000]

cVol1 = (Close > minPrice AND Average[40](Volume) > minVol)



// Trend is up and Today is an up day

cPrc1 = (Close > Average[daysToConfirmUpTrend](Close) AND Close > Open)



// Today's volume should be larger than the volume of the highest down day over the last 10 days



maxDay = 11

maxDownDay = 0

maxDown = 0



FOR d = 1 TO maxDay DO

r = Close[d] - Open[d]

IF r < 0 and Volume[d] > maxDown THEN

maxDown = Volume[d]

maxDownDay = d

ENDIF

NEXT



IF maxDownDay = 0 THEN

maxDownDayVol = 0

ELSE

maxDownDayVol = Volume[maxDownDay]

ENDIF



cVol2 = (Volume > maxDownDayVol)



// Prices just moved above 10 or 50 day SMA and [[close x SMA(10,close)] or [close x SMA(50,close)]]

cPrc2 = (Close >= Average[20](Close))

cPrc3 = (Close CROSSES OVER Average[10](Close) OR Close CROSSES OVER Average[50](Close))



// ** Other criteria to try **



// Short-Term Uptrend : 9 day MA above 20 day MA



cPrc10 = (Average[9](Close) > Average[20](Close))



// Close in Upper Half of Daily Range



cPrc11 = (Close > (High + Low) * 0.5)



// In Short-term Consolidation: close < highest high of 10 Days



cPrc12 = (Close[1] < highest[10](High))



// Not Extended or Already Broken Out: Close < highest close of 65 days



cPrc13 = (Close < highest[65](Close))



// draw indicator



ind1 = (cPrc1 AND cPrc2 AND (cPrc3 OR 1) AND cVol1 AND cVol2 AND (cPrc10 OR 1) AND (cPrc11 OR 1) AND (cPrc12 OR 1) AND (cPrc13 OR 1))





RETURN ind1 COLOURED(0, 0, 200) AS "Pivot Pocket"