This screener finds the Piercing Pattern, which is a good indicator that a potential reversal could occur. It confirms that the current candle is bullish, then it checks the previous one for the conditions of Piercing Pattern (the bullish candle closes above 50% of the preceding bearish candle, but the bullish candle opens lower than the bearish closes).

// Piercing pattern is a downtrend follow by a bullish candle
// that closes above 50% of the preceding bearish candle,
// that could indicate a reversal,
// this screener includes a fairly good confirmation of that pattern,
// it starts from a bullish candle, and it finds the pattern in the two previous candles
// @Cristofer (=
// V1

currentClose = Close
currentOpen = Open

// Bullish candle
c1 = currentOpen < currentClose

piercingHigh = High[1]
piercingClose = Close[1]
piercingOpen = Open[1]
piercingLow = Low[1]

// piercing is bullish
c2 = piercingClose > piercingOpen

bearishHigh = High[2]
bearishOpen = Open[2]
bearishClose = Close[2]
bearishLow = Low[2]

// is a bearish candle
c3 = bearishOpen > bearishClose

// lower high, lower low
c4 = bearishHigh > piercingHigh AND bearishLow > piercingLow

// piercing opens lower than bearish close
c5 = piercingOpen < bearishClose

// piercing closes above 50% level of the bearish candle
c6 = ((bearishOpen + bearishClose) / 2) < piercingClose AND piercingClose < bearishOpen

SCREENER[c1 AND c2 AND c3 AND c4 AND c5 AND c6]