True Range Breakout EUR/USD

Very nice! I like the look on BUND.

Hi, I would just like to share my own take on this strategy. I’m using 30 min on EURUSD but it works on 1H as well.
//-------------------------------------------------------------------------
// Main code : ATR breakout EURUSD 30M
//-------------------------------------------------------------------------
// EUR/USD(mini) - IG MARKETS
// TIME FRAME 30M
// SPREAD 2.0 PIPS

DEFPARAM CumulateOrders = False
DEFPARAM Preloadbars = 100
DEFPARAM FLATBEFORE = 100000
DEFPARAM FLATAFTER = 230000

once optimization = 1
once stopandtarget = 2 // 1=dynamic, 2=fixed

// VALUES
If optimization = 1 then
atrtargetlong = 1 //2
atrsllong = 1 //1
atrtargetshort = 4 //2
atrslshort = 2 //1
atrperiod = 25
atrmulit1 = 3
atrmulit2 = 2
atrtrailingstop = 1.85

elsif optimization = 2 then
atrtargetlong = 1 //2
atrsllong = 1 //1
atrtargetshort = 4 //2
atrslshort = 2 //1
atrperiod = 25
atrmulit1 = 3
atrmulit2 = 2
atrtrailingstop = 0.5
endif

// INDICATOR
atr = AverageTrueRange[atrperiod]

// LONG ENTRY
b1 = (abs(open-close) > (atr*atrmulit1))
b2 = close > open
b3 = b1 AND b2

IF b3 THEN
BUY 1 CONTRACTS AT MARKET
ENDIF

//LONG STOP AND TARGET

//Dynamic stop and target
If stopandtarget = 1 then
SET TARGET pPROFIT (atr * atrtargetlong) / pointSize
SET STOP PLOSS (atr * atrsllong) / pointSize

//Fixed stop and target
elsif stopandtarget = 2 then
SET TARGET pPROFIT 120
SET STOP PLOSS 40
ENDIF

//SHORT ENTRY
s1 = (abs(open-close) > (atr*atrmulit2))
s2 = close < open
s3 = s1 AND s2

IF s3 THEN
SELLSHORT 1 CONTRACTS AT MARKET
ENDIF

// SHORT STOP AND TARGET

//Dynamic stop and target
If stopandtarget = 1 then
SET TARGET pPROFIT (atr * atrtargetshort) / pointSize
SET STOP PLOSS (atr * atrslshort) / pointSize

//Fixed stop and target
elsif stopandtarget = 2 then
SET TARGET pPROFIT 120
SET STOP PLOSS 40
ENDIF

//trailing stop
trailingstop = (atr * atrtrailingstop) / pointSize

//resetting variables when no trades are on market
if not onmarket then
MAXPRICE = 0
MINPRICE = close
priceexit = 0
endif

//case SHORT order
if shortonmarket then
MINPRICE = MIN(MINPRICE,close) //saving the MFE of the current trade
if tradeprice(1)-MINPRICE>=trailingstop*pointsize then //if the MFE is higher than the trailingstop then
priceexit = MINPRICE+trailingstop*pointsize //set the exit price at the MFE + trailing stop price level
endif
endif

//case LONG order
if longonmarket then
MAXPRICE = MAX(MAXPRICE,close) //saving the MFE of the current trade
if MAXPRICE-tradeprice(1)>=trailingstop*pointsize then //if the MFE is higher than the trailingstop then
priceexit = MAXPRICE-trailingstop*pointsize //set the exit price at the MFE - trailing stop price level
endif
endif

//exit on trailing stop price levels
if onmarket and priceexit>0 then
EXITSHORT AT priceexit STOP
SELL AT priceexit STOP
endif