//---------------------------------------------//
//PRC_Ultimate RSI
//version = 0
//14.03.25
//Iván González @ www.prorealcode.com
//Sharing ProRealTime knowledge
//---------------------------------------------//
// inputs
//---------------------------------------------//
length=14
smotype1=3
src=close
smooth=14
smotype2=1
obValue=80
osValue=20
//---------------------------------------------//
// Augmented RSI
//---------------------------------------------//
upper=highest[length](src)
lower=lowest[length](src)
r=upper-lower
d=src-src[1]
if upper>upper[1] then
diff=r
else
if lower<lower[1] then
diff=-r
else
diff=d
endif
endif
//---------------------------------------------//
// Moving average
//---------------------------------------------//
if smotype1=1 then
num=average[length,1](diff)
den=average[length,1](abs(diff))
elsif smotype1=2 then
num=average[length,0](diff)
den=average[length,0](abs(diff))
elsif smotype1=3 then
alpha = 1/length
if barindex = length then
num = average[length](diff)
den = average[length](abs(diff))
else
num = alpha*diff + (1-alpha)*num[1]
den = alpha*abs(diff) + (1-alpha)*den[1]
endif
elsif smotype1=4 then
num=average[length](average[length](diff))
den=average[length](average[length](abs(diff)))
endif
arsi=num/den*50+50
//---------------------------------------------//
// Signal
//---------------------------------------------//
if smotype2=1 then
signal=average[smooth,1](arsi)
elsif smotype2=2 then
signal=average[smooth,0](arsi)
elsif smotype2=2 then
alpha = 1/smooth
if barindex = smooth then
signal = average[smooth](arsi)
else
signal = alpha*arsi + (1-alpha)*signal[1]
endif
elsif smotype1=3 then
signal=average[smooth](average[smooth](arsi))
endif
//---------------------------------------------//
// Plot
//---------------------------------------------//
if arsi>obvalue then
r1=0
g1=255
b1=0
a1=255
a3=0
elsif arsi<osvalue then
r3=255
g3=0
b3=0
a3=255
a1=0
else
a1=0
a3=0
endif
colorbetween(obvalue,arsi,r1,g1,b1,a1*0.3)
colorbetween(osvalue,arsi,r3,g3,b3,a3*0.3)
//---------------------------------------------//
return obValue style(dottedline),osValue style(dottedline),50 style(dottedline), arsi, signal as "Signal line"coloured("orange")style(line,2)
