oh I see now what you want. Use this version of the code:

//05.07.2018
//ALE@PROREALCODE
//https://www.automatictrading.it/
////////////////////////////////////////////////////////////
TranslateCandle            =0       //  To maintain both the candles on the graph without overlap
TransRange                 =0.01    //  To choose distance of the 3D caNdle
Transparency               =0
////////////////////////////////////////////////////////////
ONCE CandleCci             =1       // CANDLE + COMMODITY CHANNEL INDEX COLOUR
ONCE CandleRsi             =0       // CANDLE + RSI COLOUR
ONCE CandleStochastic      =0       // CANDLE + STOCASTIC COLOUR
ONCE CandleCycle           =0       // CANDLE + CYCLE COLOUR
ONCE CandleDI              =0       // CANDLE + DIRECTIONAL INDEX COLOUR
 
//////////////////////////////V//////////////////////////////
ONCE CciPeriod             =20
ONCE RsiPeriod             =14
ONCE N                     =14
ONCE K                     =3
ONCE DiPeriod              =14
 
//////////////////////////////V//////////////////////////////
 
If CandleCci then                                 // CANDLE + COMMODITY CHANNEL INDEX COLOUR
MyCci  = Cci[max(1,CciPeriod)](customclose)
R = (200-MyCci)
G =(200+MyCci)
if TranslateCandle then
DRAWCANDLE(open-(open*TransRange*pointsize), high-(high*TransRange*pointsize), low-(low*TransRange*pointsize), close-(close*TransRange*pointsize)) Coloured (R,G,0,transparency*50)
else
DRAWCANDLE(open, high, low, close) Coloured (R,G,0,transparency*50)
endif
Elsif CandleRsi then                           // CANDLE + RSI COLOUR
MyRsi    = RSI[max(1,RsiPeriod)](customclose)
R =50+(200-(MyRsi-50)*12)
G =50+(200+(MyRsi-50)*12)
if TranslateCandle then
DRAWCANDLE(open-(open*TransRange*pointsize), high-(high*TransRange*pointsize), low-(low*TransRange*pointsize), close-(close*TransRange*pointsize)) Coloured (R,G,0,transparency*50)
else
DRAWCANDLE(open, high, low, close) Coloured (R,G,0,transparency*50)
endif
Elsif CandleStochastic then                           // CANDLE + STOCHASTIC COLOUR
MyStoch    = Stochastic[max(1,N),max(1,K)](customclose)
R =50+(200-(MyStoch-50)*6)
G =50+(200+(MyStoch-50)*6)
if TranslateCandle then
DRAWCANDLE(open-(open*TransRange*pointsize), high-(high*TransRange*pointsize), low-(low*TransRange*pointsize), close-(close*TransRange*pointsize)) Coloured (R,G,0,transparency*50)
else
DRAWCANDLE(open, high, low, close) Coloured (R,G,0,transparency*50)
endif
Elsif CandleCycle then                           // CANDLE + CYCLE COLOUR
MyCycle    = Cycle(customclose)
R = (200-MyCycle*10)
G =(200+MyCycle*10)
if TranslateCandle then
DRAWCANDLE(open-(open*TransRange*pointsize), high-(high*TransRange*pointsize), low-(low*TransRange*pointsize), close-(close*TransRange*pointsize)) Coloured (R,G,0,transparency*50)
else
DRAWCANDLE(open, high, low, close) Coloured (R,G,0,transparency*50)
endif
Elsif CandleDI then                              // CANDLE + DIRECTIONAL INDEX
MyDi = DI[max(1,DiPeriod)](customclose)
R = 50+(200-MyDi*10)
G =50+(200+MyDi*10)
if TranslateCandle then
DRAWCANDLE(open-(open*TransRange*pointsize), high-(high*TransRange*pointsize), low-(low*TransRange*pointsize), close-(close*TransRange*pointsize)) Coloured (R,G,0,(transparency)*50)
else
DRAWCANDLE(open, high, low, close)Coloured (R,G,0,transparency*50)
endif
 
endif
 
Return close coloured(r,g,0)

and set your price setting to a line (otherwise you will still see the normal candlestick of the price chart).

DAX-1-hour.png

Hi there,

I used a customised RSI Dominant Cycle and standard RSI but although the code looks okay (?), when I launched it on the price chart it now sits just below the current prices/candlesticks?
So I have two price series candlesticks, one green/white and the other the 3D candles! Any ideas? For those without the code it’s on this forum somewhere but here it is:

Period = CALL "Ehler's Dominant Cycle Modify" 
DC = MAX(8, MIN(Round(Period),48) ) 
myRSI = RSI[DC](close) 
Return myRSI coloured(0,255,255) as "RSIdc"

//PeriodDC= 20  //   original by John Ehlers
PeriodDC= MAX(8, MIN(DC, 48))
 
IF barindex = 1 THEN
BP= 0.01
DC= 20
 
ELSIF Barindex >= 2 THEN
REM ---------------------------------------------
REM Highpass Filter and BP or SuperSmoother Filter together form a Roofing Filter
REM ---------------------------------------------
HPPrice= close
HPPeriod= PeriodDC
HPBandwidth= 0.3    // 0.7 original Dominant Cycle Measured, 0.3 (0.10-0.50) from Roofing Filter
HPalpha= (COS(0.25*HPBandwidth*360/HPPeriod) + SIN(0.25*HPBandwidth*360/HPPeriod)-1) / COS(0.25*HPBandwidth*360/HPPeriod)
HP= (1+HPalpha/2)*(HPPrice-HPPrice[1]) + (1-HPalpha)*HP[1]
 
BPPrice= HP
BPPeriod= PeriodDC
BPBandwidth= HPBandwidth
beta= COS(360/BPPeriod)
gamma= 1/COS(360*BPBandwidth/BPPeriod)
BPalpha= gamma - SQRT(gamma*gamma-1)
BP= 0.5*(1-BPalpha)*(BPPrice-BPPrice[2]) + beta*(1+BPalpha)*BP[1] - BPalpha*BP[2]
 
REM ---------------------------------------------
REM Calculation of Dominant Cycle by counting Zero crossing of BP
REM ---------------------------------------------
CountPrice= BP
DC= DC[1]
DC= MAX(6, DC)
counter= counter + 1
IF CountPrice CROSSES OVER 0 OR CountPrice CROSSES UNDER 0 THEN
DC= 2*counter
ThrashH= 1.11   // original 1.25
IF 2*counter > ThrashH*DC[1] THEN
DC= ThrashH*DC[1]
ENDIF
ThrashL= 0.90   // original 0.8
IF 2*counter < ThrashL*DC[1] THEN
DC= ThrashL*DC[1]
ENDIF
counter= 0
ENDIF
 
ENDIF
 
DC= MAX(8, MIN(DC, 48))
 
RETURN DC coloured(0,255,255) as "DomCyclePeriod"
//, BP coloured(0,255,0,255) as "BandPass"

Cheers,

Bard

Brent-Crude-2-prices-with-3d-candles.png