// Definizione dei parametri del codice
DEFPARAM CumulateOrders = true // Posizioni cumulate attivate
//Il sistema cancellerà tutti gli ordini in attesa e chiuderà tutte le posizioni a 0:00. Dopo l’orario "Flat Before" non saranno piazzati nuovi ordini o posizioni.
// Il sistema cancellerà tutti gli ordini in attesa e chiuderà tutte le posizioni a 0:00. Dopo l’orario "Flat Before" non saranno piazzati nuovi ordini o posizioni.
DEFPARAM FLATBEFORE = 070000
// Cancellare tutti gli ordini in attesa e chiudere tutte le posizioni all’orario "Flat After"
DEFPARAM FLATAFTER = 230000
TIMEFRAME(default)
// Impedisce al sistema di tradare in giorni specifici della settimana
daysForbiddenEntry = OpenDayOfWeek = 6 OR OpenDayOfWeek = 0
//
//////////////////////////////////////////////////////////////////////////////////
ONCE risk = 150 //max. capitale da rischiare
ONCE PipNum = risk / pipvalue //Numero di Pips in base al rischio
ONCE lotti = 1 //1 lotto per difetto
//ONCE MinLotti = 0.5 //Numero minimo di lotti
MyATR = (AverageTrueRange[7](close) / pipsize)*4.2
Pips = max(0,min(PipNum,MyATR)+12)
Lotti = PipNum / pips
//////////////////////////////////////////////////////////////////////////////////
//
// Condizioni per entrare su posizioni long
indicator1 = Average[1](Stochastic[3,1](close))
c1 = (indicator1 CROSSES OVER 20)
//
TIMEFRAME(1 hour,default)
indicator2 = ExponentialAverage[9](close)
indicator3 = ExponentialAverage[21](close)
c2 = (indicator2[1] > indicator3[1])
//
TIMEFRAME(default)
IF (c1 AND c2) AND not daysForbiddenEntry and not onmarket THEN
BUY Lotti SHARES AT MARKET
SET STOP pLOSS Pips
SET TARGET pPROFIT (Pips * 3)
ENDIF
// Condizioni per entrare su posizioni short
indicator4 = Average[1](Stochastic[3,1](close))
c3 = (indicator4 CROSSES UNDER 80)
//
TIMEFRAME(1hour,default)
indicator5 = ExponentialAverage[9](close)
indicator6 = ExponentialAverage[21](close)
c4 = (indicator5[1] < indicator6[1])
//
TIMEFRAME(default)
IF (c3 AND c4) AND not daysForbiddenEntry and not onmarket THEN
SELLSHORT Lotti SHARES AT MARKET
SET STOP pLOSS Pips
SET TARGET pPROFIT (Pips * 3)
ENDIF
TIMEFRAME (5minute,upDateOnClose)
//************************************************************************
//trailing stop function
trailingstart = 50//trailing will start @trailinstart points profit
trailingstep = 25//trailing step to move the "stoploss"
//reset the stoploss value
IF NOT ONMARKET THEN
newSL=0
ENDIF
//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
IF newSL=0 AND close-tradeprice(1)>=trailingstart*pipsize THEN
newSL = tradeprice(1)+trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
newSL = newSL+trailingstep*pipsize
ENDIF
ENDIF
//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
newSL = tradeprice(1)-trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
newSL = newSL-trailingstep*pipsize
ENDIF
ENDIF
//stop order to exit the positions
IF newSL>0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF
//
.
