//after the enrty (long or short) this TS is meant to do more entry until the Stoploss or the Takeprofit will be reached. The stop loss is not static but it is decided at the beginning with variable riskpercent. When the system makes the second, third ,fourth, etc entries the SL is moved to guarantee that the risk is always the same (it means that at every new buy signal it is moved more near to the avarage price.
//The Take profit is done when the atual gain is under the avarage of the last trades and when the risk reward ratio is reached
defparam preloadbars = 100
once RRreached = 0
//parameters
indexvalue = 10000 //dax=10000 MIB=18000 WTI=4800 etc...
Entrysteps = 0.25 // decide with which interval the new entries are done
accountbalance = 10000 //account balance in money at strategy start
riskpercent = 1 //whole account risk in percent%
gridstep = indexvalue*(riskpercent/100*Entrysteps) //grid step in point, this should change depending on the volatility
amount = 1 //lot amount to open each trade
rr = 3//risk reward ratio (set to 0 disable this function)
//first trade whatever condition. Here you should put the entry of long trades. this one below is only an example.
if NOT ONMARKET AND close>close[1] then
BUY amount LOT AT MARKET
endif
//first trade whatever condition. Here you should put the entry of short trades. this one below is only an example.
if NOT ONMARKET AND close<close[1] then
SELLSHORT amount LOT AT MARKET
endif
// case BUY - add orders on the same trend. Here is when next buy are made
if longonmarket and close-tradeprice(1)>=gridstep*pipsize then
BUY amount LOT AT MARKET
endif
// case SELL - add orders on the same trend. Here is when next sell are made
if shortonmarket and tradeprice(1)-close>=gridstep*pipsize then
SELLSHORT amount LOT AT MARKET
endif
//money management
liveaccountbalance = accountbalance+strategyprofit //balance account considering the past trades
moneyrisk = (liveaccountbalance*(riskpercent/100)) //value in euro that we risk on each trade.
if onmarket then
onepointvaluebasket = pointvalue*countofposition //value of each point of the index. It increase when we have multiples contracts
mindistancetoclose =(moneyrisk/onepointvaluebasket)*ticksize //index points calculated to keep the stoploss fixed
endif
//floating profit
floatingprofit = ((close-positionprice)*pointvalue)*countofposition //actual trade gains
MAfloatingprofit = average[20](floatingprofit)//avarage of the last 20 trades
BBfloatingprofit = MAfloatingprofit - std[20](MAfloatingprofit)*2 //standard deviation of the avarage of last 20 trades
//floating profit risk reward check. If the actual gain is bigger than the riskreward the variable RRreached is set to 1. It means that the system is ready to exit at the take profit signal.
if rr>0 and floatingprofit>moneyrisk*rr then
RRreached=1
endif
//Here is where we set the stoploss. it means that the reward ratio is not reached yet.
if onmarket and RRreached=0 then
SELL AT positionprice-mindistancetoclose STOP
EXITSHORT AT positionprice-mindistancetoclose STOP
endif
//stoploss trigger when risk reward ratio has been reached.
//If the risk reward is reached the take profit can be done. The Take profit is done when the atual gain is under the avarage of the last trades
if onmarket and RRreached=1 then
if floatingprofit crosses under BBfloatingprofit then
SELL AT MARKET
EXITSHORT AT MARKET
RRreached = 0 //resetting the risk reward reached variable
endif
endif
//resetting the risk reward reached variable
//if not onmarket then
//RRreached = 0
//endif
//GRAPH average[10](strategyprofit) coloured(0,0,255) as "profit curve"
//HOW TO MAKE IT BETTER: About ATR step instead of fixed one is clever. But, since we want to quickly make huge profit, I suggest to add more orders when the ATR is high and less when it is low. So when the ATR rise a lot in short period, it means that actual volatility can guarantee that a lot of grid orders can be launched to grow the floating profit. Then BB exit would take care of the rest. Of course, we are talking of backtest, live environment should not the exact same thing as market slippage can take its part into making trouble.
.
