Hi all,

So I took the premise above and created a little something. The general idea is that if the break of yesterday’s daily high/low (whichever comes first) fails, then a stop and reverse x points away at double the position size is likely to make up for it.

I tested this out on FTSE. On its own the idea doesn’t work. But once you put in a trend filter (in this case long term MA), it starts to become promising. Below is just a quick version I threw together – a skeleton if you like, which gets the orders in the right places according to the rules above  – so not finished work by any means.

There are probably some cleaver filters which could be fitting here (ADX, FDI, volume, oscillators, seasonality, etc etc) – so I invite anyone to take a look, have a play around and contribute; as well as test it out on different instruments / asset classes.

// FTSE M30

// Notes

// Things to try for the next versions
// -- Seasonailty
// -- Day of week biasing
// -- Day of month biasing
// -- Correlated market biasing (in house platform)
// -- ATR based stops and limits
// -- ATR based or range based (or both based) flip distances
// -- Trailing and donchian stops
// -- momentum and trend filters


// -- System Parameters
DEFPARAM FLATBEFORE = 010000 // UK time zone
DEFPARAM FLATAFTER  = 163000 // UK time zone
DEFPARAM cumulateOrders = false

// -- Position sizing --
firstPositionSize = 1
secondPositionSize = 2 // maybe do some dynamic magic with this ?

// UK FTSE Opening hours (GMT+/-0)
// Adjust for your market and time zone
once marketOpen  = 080000
once marketClose = 163000

// -- Variable set selection --
once optimization = 1

if optimization = 1 then                   // FTSE M30
// flipDistance        = 17 // 15 // originally 40
// firstTradeTarget    = 134 // 87
// secondTradeTarget   = 144 //87
// maLongPeriod        = 207
endTime = 160000
startTime = 080000
//startTimeOffset = 120000 // done this way for optimizer to work
//000000+startTimeOffset
tradingTime = time > startTime and time < endTime
endif


// -- Indicators -----

// -- Low and high of actual trading day (not the 24 hour market)
once startBarIndex = 0
if time = marketClose then
yHigh = highest[barIndex-startBarIndex](high)
yLow  = lowest[barIndex-startBarIndex](low)
//doneForTheDay = 0

// Stop and reverse levels for long and short side
flipDistance = flipDistanceRangeMultiple * (yHigh - yLow)
shortFlipLevel = yHigh-(flipDistance*pipSize)
longFlipLevel  = yLow +(flipDistance*pipSize)

elsif time = marketOpen then
startBarIndex = barIndex
endif

// reset
if time = startTime then
tradesPlaced   = 0
sellOrderLevel = undefined
buyOrderLevel  = undefined
stopTarget     = undefined
stopLoss       = 999999999 // off
endif

withinRange = close < yHigh and close > yLow
// -- Common indicators -----
maLong = average[maLongPeriod, 1](Close)

// -- Filters -----
// only long if...
fLong = maLong > maLong[1]
// only short if...
fShrt = maLong < maLong[1]


bo1 = withinRange and not onMarket and tradingTime
bo1 = bo1 and tradesPlaced = 0
bo1 = bo1 and fLong

so1 = withinRange and not onMarket and tradingTime
so1 = so1 and tradesPlaced = 0
so1 = so1 and fShrt

bo2 = shortOnMarket and tradingTime and tradesPlaced = 1
bo2 = bo2 and not bo1 and abs(countOfPosition) = firstPositionSize

so2 = longOnMarket and tradingTime and tradesPlaced = 1
so2 = so2 and not so1 and abs(countOfPosition) = firstPositionSize

if bo1 then
orderSize     = firstPositionSize
buyOrderLevel = yHigh
stopTarget = firstTradeTarget
endif

if so1 then
orderSize = firstPositionSize
sellOrderLevel = yLow
stopTarget = firstTradeTarget
endif

if bo2 then
orderSize = secondPositionSize
stopTarget = secondTradeTarget
stopLoss   = secondTradeStopLoss
buyOrderLevel = longFlipLevel
endif
if so2 then
orderSize = secondPositionSize
stopTarget = secondTradeTarget
stopLoss   = secondTradeStopLoss
sellOrderLevel = shortFlipLevel
endif


// -- Order placing --
if bo1 or bo2 then
buy orderSize shares at buyOrderLevel stop
endif
if so1 or so2 then
sellShort orderSize shares at sellOrderLevel stop
endif
if bo1 or so1 or bo2 or so2 then
set stop pLoss stopLoss // not really used currently
set target pProfit stopTarget
endif


// keep track of open trades
if onMarket then
if not onMarket[1] then
tradesPlaced = 1
elsif countOfPosition = secondPositionSize then
tradesPlaced = 2
endif
endif

//graph tradesPlaced

I’ll see if I can take another look at this when I get the time.

All the best,

Maz