// TS name: Historical Maximum Breakout
// Description: Buy at pivot highs breakouts.
// Sell at relative minimums (or lows) between the
// breakout of a pivot high and that pivot high
// A pivot high is confirmed by a correction in the low
// of the bar(s) after a new historical maximum
// Instruments: Stocks/ETFs
// Time frame: Daily / preferibly weekly or monthly
// Features: Long only system. No money management
// Version: 03.1
// ****************************************************************************
// customizable and optional parameters
once positionSize = 2000 // Fixed capital
once exitFilter = 3 // % below relative minimum to exit position
// variables declaration
once historicMax = 0 // pivot high
once currentMax = 0 // current maximum candidate to pivot high
once barHistoricMax = 0 // pivot high barIndex
once barCurrentMax = 0 // current maximum barIndex
once exitPrice = 0 // exit price
once buyPrice = 0 // buy price
once lowBar0 = 0 // stores low of 'tricky' first loaded bar
//
if barIndex = 0 then
lowBar0 = low
endif
if high >= currentMax then
//keep track of candidates to new pivot high
currentMax = high
barCurrentMax = barIndex
elsif high < currentMax and currentMax > historicMax then
if low < low[1] then
// correction so update pivot high and buy price
historicMax = currentMax
barHistoricMax = barCurrentMax
buyPrice = historicMax
endif
endif
if high > historicMax then
// update exit price
if barhistoricMax = 0 then
exitprice=min(lowbar0,lowest[barIndex - barHistoricMax](low) * (1 - exitFilter/100))
else
exitPrice = lowest[barIndex - barHistoricMax](low) * (1 - exitFilter/100)
endif
endif
// open position at new pivot high
if not onmarket and buyPrice > 0 then
buy positionSize cash at buyPrice stop // set buy stop order
endif
// close position at exitPrice
if onmarket and exitPrice > 0 then
sell at exitPrice stop // set sell stop order
endif
//graph exitPrice
.
