Hola a todos, No encuentro un indicador que muestre gráficamente el resultado de una estrategia determinada. Existe alguna manera en PRT?. Gracias
Hola
No lo hay. Lo que sí podrías hacer es simular la estrategia creando el indicador, similar a cuando haces backtesting pero sustituyendo las líneas de buy, sell con otras.
Te pongo un ejemplo:
if tuscondiciones and largo=0 then
largo=1
drawarrowup(barindex,low-tr*0.25)coloured(0,250,0)
endif
if largo and tuscondiciones then
largo=0
drawarrowdown(barindex,high+tr*0.25)coloured(250,0,0)
endif
Se puede complicar mucho más almacenando y mostrando los datos resultado estrategia, %acierto, promedio ganadoras, etc, etc
No sé si es eso lo que estás buscando
thanked this post
Muchas gracias por responder Iván. Cómo se podrían unir los puntos (flechas) de las operaciones y que aparezca como una especie de media?. Un saludo Iván
Tendrías que crear variables que almacenasen el precio de entrada, el precio de salida y el número de días que ha estado abierta la posición. De esta forma luego puedes utilizar la opción drawsegment para dibujar una línea que vaya desde el precio de entrada hasta el precio de salida, incluso distinguiendo operaciones ganadoras de operaciones perdedoras.
No sé si es a esto a lo que te refieres.
Te pongo un ejemplo
ema10 = average[10,1](close)
ema50 = average[50,1](close)
if largo = 0 and ema10 crosses over ema50 then
largo = 1
buyprice = close
drawarrowup(barindex,low-tr*0.25)coloured(0,250,0)
drawpoint(barindex,buyprice,2)coloured(0,0,250)
endif
if largo = 1 then
bars = bars+1
if ema10 crosses under ema50 then
largo = 0
sellprice = close
drawarrowdown(barindex,high+tr*0.25)coloured(250,0,0)
drawpoint(barindex,sellprice,2)coloured(0,0,250)
resultado = sellprice-buyprice
if resultado > 0 then
r=0
g=250
else
r=250
g=0
endif
drawsegment(barindex-bars+1,buyprice,barindex,sellprice)coloured(r,g,0)
bars = 0
endif
endif
return
thanked this post
Hola Iván, muchas gracias por responder. Lo que estoy buscando es un indicador que haga lo que hace la gráfica de un PROORDER con la evolución de pérdidas y ganancias (curva de liquidez). Te adjunto una imagen ejemplo.
???????????????????????????????
Buenas
Aquí tendrías una aproximación:
//DEFPARAM DRAWONLASTBARONLY = true
REM INDICADORES Y PARÁMETROS DEL SISTEMA
ONCE DENTRO = 0
ema10 = average[10](CLOSE)
ema60 = average[60](close)
///////////ESTRATEGIA LARGOS///////////////////
c1 = ema10 CROSSES OVER ema60
IF DENTRO=0 AND c1[1] THEN
DENTRO = 1
BUYPRICE = open
REM CALCULAMOS EL NÚMERO DE ACCIONES QUE HAY QUE COMPRAR
TITULOS = ROUND(10000/BUYPRICE)
ENDIF
//////////////////CONDICIONES SALIDA///////////////////
S1 = ema10 crosses under ema60
IF DENTRO=1 AND s1[1] THEN
DENTRO=0
REM VEMOS A QUÉ PRECIO SALIMOS EN FUNCIÓN DE LA CONDICIÓN DE SALIDA
SELLPRICE = OPEN
REM ALMACENAMOS LOS RESULTADOS DE LA OPERACIÓN
RESULTADO = (SELLPRICE-BUYPRICE)*TITULOS
REM CALCULAMOS EL CAPITAL DESPUÉS DE LA OPERACIÓN
BENEFICIO = BENEFICIO[1]+RESULTADO
ENDIF
RETURN BENEFICIO AS "BENEFICIO"//100000+BENEFICIO AS "CAPITAL"
thanked this post
Muchas gracias Iván. Voy a investigar con esta base que has aportado. Saludos
