defparam drawonlastbaronly=true
percent = 10 //max percent of change for range and body in the serie
BarsLookback = 3 //quantity of candles to scan in a event serie
BarsAfterward = 30 //quantity of candles to check gain after the event
// ------------
body = abs(open-close)
bodyVar = (body-body[1])/body[1]*100
rangeVar = (range-range[1])/range[1]*100
test = bodyVar<=percent and rangeVar<=percent //testing variation of a single candle
varq = summation[max(1,Barslookback-1)](test)=Barslookback-1 //testing variation of a serie
if varq and barindex-$seriebar[max(0,lastset($serieBar))]>1 then //save the occurence data into array
$serieBar[lastset($serieBar)+1]=barindex
$seriePrice[lastset($serieBar)+1]=close
endif
if islastbarupdate and lastset($serieBar)>0 then
//loop through the series to classify the gain stats
up=0
dn=0
upcount=0
dncount=0
for j = 0 to lastset($serieBar) do
if barindex-$serieBar[j]>=BarsAfterWard then
ibar=barindex-($serieBar[j]+BarsAfterWard)
gain=(close[ibar]-$seriePrice[j])/pointsize //compute the gain
if gain>0 then //up
up=up+gain
upcount=upcount+1
else //down!
dn=dn+gain
dncount=dncount+1
endif
endif
next
//compute the average per side
upavg=up/upcount
dnavg=dn/dncount
drawtext("up move=#upcount#",barindex+20,upavg/2,dialog,standard,20) coloured(0,200,0)
drawtext("dn move=#dncount#",barindex+20,dnavg/2,dialog,standard,20) coloured(200,0,0)
endif
return upavg coloured(0,168,0) style(histogram,3) as "average up move", dnavg coloured(200,0,0) style(histogram,3) as "average down move"
.
