who can

If you are using PRT v11 then you can just use my indicator:

Every Fractal trend lines

I just reread your first post and I see that there is the additional criteria that the most recent swing low is higher than the second most recent and the opposite for swing highs.

In v10 we would need to use loops to search back and find each swing high/low and then exit the loop when we find two that meet our criteria – either that or store a mass of individual variables which is all a bit slow and cumbersome. In v11 everything is much easier with the availability of arrays as we can store every swing high/low that there has ever been in a single variable name. The code would be quite simple except if ever there has not been a lower swing low than the latest one or a higher swing high than the latest one because then we need to check back comparing to the second latest swing high/low and so on and so on. If a market has bottomed out at an all time low and formed a swing high there then we won’t be able to find a lower swing low further back in the data.

v11 also has the ability to draw into the future which v10.3 does not which makes projecting lines forward much easier.

IG are rolling out v11 country by country at the moment so I can’t imagine that it will be long before Australia gets it.

I’m a little bit busy with other things at the moment to get started on a new code and I am only coding in v11 now rather than struggle to achieve things I want in v10.3. Hopefully someone else can help you with v10.3 code or let me know when you get v11 and I will try to find some time to code something.

It didn’t need much time! Here is a version that checks the latest fractal and looks back for a fractal that meets the criteria. If there isn’t one then it uses the second last fractal and does the same checks. Not extensively tested!

//parthapersonal Fractals v1.1
//PRT v11
//By Vonasi
//Date: 20201217

defparam drawonlastbaronly = true
//Settings
//BarsBefore = 1
//BarsAfter = 1
//Support = 1
//Resistance = 1
//Points = 1

//Make sure all settings are valid ones
BarsBefore = max(BarsBefore,1)
BarsAfter = max(BarsAfter,1)
StartBack = max(0,startback)

if barindex >= barsbefore + barsafter then

//Look for a low fractal
BarLookBack  = BarsAfter + 1
if low[BarsAfter] < lowest[BarsBefore](low)[BarLookBack] THEN
if low[BarsAfter] = lowest[BarLookBack](low) THEN
a = a + 1
$supportbar[a] = barindex[barsafter]
$supportvalue[a] = low[barsafter]
endif
endif

//Look for a high fractal
if high[BarsAfter] > highest[BarsBefore](high)[BarLookBack] THEN
if high[BarsAfter] = highest[BarLookBack](high) THEN
b = b + 1
$resistancebar[b] = barindex[barsafter]
$resistancevalue[b] = high[barsafter]
endif
endif

if islastbarupdate then
//support line
if a >= 2 then
if support then
flag = 0
zz = 0
for z = a-zz downto 0
for xx = 1 to a
if $supportvalue[z] > $supportvalue[z-xx] then
drawray($supportbar[z-xx],$supportvalue[z-xx],$supportbar[z],$supportvalue[z]) coloured(128,0,0)
if points then
drawpoint($supportbar[z],$supportvalue[z],2) coloured(128,0,0)
drawpoint($supportbar[z-xx],$supportvalue[z-xx],2) coloured(128,0,0)
endif
flag = 1
break
endif
zz = zz + 1
next
if flag = 1 then 
break
endif
zz = 0
next
endif
endif

//resistance line
if b >= 2 then
if resistance then
flag = 0
zz = 0
for z = b-zz downto 0
for xx = 1 to b
if $resistancevalue[z] < $resistancevalue[z-xx] then
drawray($resistancebar[z-xx],$resistancevalue[z-xx],$resistancebar[z],$resistancevalue[z]) coloured(0,128,0)
if points then
drawpoint($resistancebar[z],$resistancevalue[z],2) coloured(0,128,0)
drawpoint($resistancebar[z-xx],$resistancevalue[z-xx],2) coloured(0,128,0)
endif
flag = 1
break
endif
zz = zz + 1
next
if flag = 1 then
break
endif
zz = 0
next
endif
endif

endif
endif

return