Defparam cumulateorders = false
// At 5 am I define the width of the canal (RangeBreakout) and its extremes (HH and LL)
// Furthermore, I set the TradeLong and TradeShort variables to zero
IF TIME = 050000 THEN
HH = highest[8](high)
LL = lowest[8](low)
TradeLong = 0
TradeShort = 0
RangeBreakout = HH-LL
ENDIF
//I define the condition that requires working in a specific time interval
Condtime = time >= 050000 AND time <= 180000
// I define the condition that requires the closing price to be inside the channel
Condchannel = close < HH and close > LL
// If the Condchannel and CondTime conditions are met ...
IF Condtime and Condchannel THEN
IF TradeLong = 0 THEN
buy at HH stop //... and if the system is not Long, then buy at the breaking of the upper end of the channel
ELSIF TradeShort = 0 THEN
sellshort at LL stop //... and if the system is not Short, then it sells at the breaking of the lower end of the channel
ENDIF
ENDIF
// If the position is long, set the value of the TradeLong variable to 1
IF longonmarket THEN
TradeLong = 1
ENDIF
// If the position is short, set the value of the TradeShort variable to 1
IF shortonmarket THEN
TradeShort = 1
ENDIF
// Set a stop loss equal to the width of the channel
set stop loss RangeBreakout
// Set a profit equal to a percentage of the channel width
set target profit RangeBreakout*Tgt
graph Condtime
graph Condchannel
graph TradeLong
graph TradeShort
graph HH
graph LL
.
