// pathfinder system @ ger40 version 3
// timezone europetime berlin
// timeframe 4H
// 2 points spread
// Dax breakout system triggered by previous daily, weekly and monthly high/low crossings
// Original by Reiner , refresh by JohnScher @ 07/31/2022
// proOrder code parameter
DEFPARAM CUMULATEORDERS = true // cumulate orders if not turned off
DEFPARAM PRELOADBARS = 10000
// smoothed average parameter (signalline)
ONCE periodFirstMA = 5
ONCE periodSecondMA = 10
ONCE periodThirdMA = 3
// filter parameter
ONCE periodLongMA = 250
ONCE periodShortMA = 50
// trading paramter
ONCE PositionSize = 1
// money and position management parameter
ONCE stoppLoss = 5 // in %
ONCE takeProfitLong = 5 // in %
ONCE takeProfitShort = 2 // in %
ONCE maxCandlesLongWithProfit = 20 // take long profit latest after 18 candles
ONCE maxCandlesShortWithProfit = 17 // take short profit latest after 13 candles
ONCE maxCandlesLongWithoutProfit = 30 // limit long loss latest after 30 candles
ONCE maxCandlesShortWithoutProfit = 30 // limit short loss latest after 25 candles
// calculate daily high/low
dailyHigh = DHigh(1)
dailyLow = DLow(1)
// calculate weekly high/low
If DayOfWeek < DayOfWeek[1] then
weeklyHigh = Highest[BarIndex - lastWeekBarIndex](dailyHigh)
lastWeekBarIndex = BarIndex
ENDIF
// calculate monthly high/low
If Month <> Month[1] then
monthlyHigh = Highest[BarIndex - lastMonthBarIndex](dailyHigh)
monthlyLow = Lowest[BarIndex - lastMonthBarIndex](dailyLow)
lastMonthBarIndex = BarIndex
ENDIF
// calculate signalline with multiple smoothed averages
firstMA = WilderAverage[periodFirstMA](close)
secondMA = TimeSeriesAverage[periodSecondMA](firstMA)
signalline = TimeSeriesAverage[periodThirdMA](secondMA)
// filter criteria because not every breakout is profitable
c1 = close > Average[periodLongMA](close)
c2 = close < Average[periodLongMA](close)
c3 = close > Average[periodShortMA](close)
c4 = close < Average[periodShortMA](close)
// long position conditions
l1 = signalline CROSSES OVER monthlyHigh
l2 = signalline CROSSES OVER weeklyHigh
l3 = signalline CROSSES OVER dailyHigh
l4 = signalline CROSSES OVER monthlyLow
// long timebased conditions
tmLong = openmonth <> 1 and openmonth <> 9
tdLong = opendayofweek >= 1 and opendayofweek <= 4 //sik!
ttLong = time >= 090000 and time <= 210000
// short position conditions
s1 = signalline CROSSES UNDER monthlyHigh
s2 = signalline CROSSES UNDER monthlyLow
s3 = signalline CROSSES UNDER dailyLow
// short timebased conditions
tmShort = openmonth <> 3 and openmonth <> 5 and openmonth <> 10 and openmonth <> 11
tdShort = opendayofweek >= 1 and opendayofweek <= 5
ttShort = time >= 090000 and time <= 210000
// long entry
IF tmLong and tdLong and ttLong then
IF ( l1 OR l4 OR l2 OR (l3 AND c2) ) THEN // cumulate orders for long trades
BUY PositionSize CONTRACT AT MARKET
takeProfit = takeProfitLong
ENDIF
Endif
// short entry
IF tmShort and tdShort and ttShort THEN
IF ( (s1 AND c3) OR (s2 AND c4) OR (s3 AND c1) ) THEN // no cumulation for short trades
SELLSHORT positionSize CONTRACT AT MARKET
takeProfit = takeProfitShort
ENDIF
ENDIF
// stop and profit management
posProfit = (((close - positionprice) * pointvalue) * countofposition) / pipsize
m1 = posProfit > 0 AND (BarIndex - TradeIndex) >= maxCandlesLongWithProfit
m2 = posProfit > 0 AND (BarIndex - TradeIndex) >= maxCandlesShortWithProfit
m3 = posProfit < 0 AND (BarIndex - TradeIndex) >= maxCandlesLongWithoutProfit
m4 = posProfit < 0 AND (BarIndex - TradeIndex) >= maxCandlesShortWithoutProfit
IF LONGONMARKET AND (m1 OR m3) THEN
SELL AT MARKET
ENDIF
IF SHORTONMARKET AND (m2 OR m4) THEN
EXITSHORT AT MARKET
ENDIF
SET STOP %LOSS stoppLoss
SET TARGET %PROFIT takeProfit
.
