// Pathfinder DAX 4H, 8-22, 2 points spread
// DAX breakout system triggered by daily, weekly and monthly high/low crossings
// code-parameter
DEFPARAM CUMULATEORDERS = true
// trading window
ONCE StartTime = 80000
ONCE EndTime = 220000
// money management
ONCE PositionSize = 1
// trading parameter
ONCE sl = 3
ONCE tp = 1.5
// calculate weekly high/low
If DayOfWeek < DayOfWeek[1] then
weeklyHigh = Highest[BarIndex - lastWeekBarIndex](DHigh(1))
lastWeekBarIndex = BarIndex
ENDIF
// calculate monthly high/low
If Month <> Month[1] then
monthlyHigh = Highest[BarIndex - lastMonthBarIndex](DHigh(1))
monthlyLow = Lowest[BarIndex - lastMonthBarIndex](DLow(1))
lastMonthBarIndex = BarIndex
ENDIF
// calculate signalline with multiple smoothed averages
firstMA = WilderAverage[5](close)
secondMA = TimeSeriesAverage[10](firstMA)
signalline = TimeSeriesAverage[5](secondMA)
// position management during trading window
IF Time >= StartTime AND Time <= EndTime THEN
// filter criteria because not every break is profitable
c1 = close > Average[200](close)
c2 = close < Average[200](close)
c3 = close > Average[50](close)
c4 = close < Average[50](close)
// long position conditions
l1 = signalline CROSSES OVER monthlyHigh
l2 = signalline CROSSES OVER weeklyHigh
l3 = signalline CROSSES OVER DHigh(1)
l4 = signalline CROSSES OVER monthlyLow
// long entry
IF ( l1 OR l4 OR l2 OR (l3 AND c2) ) THEN // cumulate orders for long trades could be a performance booster
BUY PositionSize CONTRACT AT MARKET
ENDIF
// short position conditions
s1 = signalline CROSSES UNDER monthlyHigh
s2 = signalline CROSSES UNDER monthlyLow
s3 = signalline CROSSES UNDER Dlow(1)
// short entry
IF NOT SHORTONMARKET AND ( (s1 AND c3) OR (s2 AND c4) OR (s3 AND c1) ) THEN // no cumulation for short trades
SELLSHORT PositionSize CONTRACT AT MARKET
ENDIF
// stop and profit
SET STOP %LOSS sl
SET TARGET %PROFIT tp
ENDIF
.
