//---------------------------------------------------//
//version = 0
//12.12.2024
//Iván González @ www.prorealcode.com
//Sharing ProRealTime knowledge
//---------------------------------------------------//
//Inputs
//---------------------------------------------------//
defparam drawonlastbaronly=true
src1 = low//min(open,close)
src2 = high//max(open,close)
//leftbars=40
//rightbars=10
//tol=5 //%
$type[0]=1
//---------------------------------------------------//
//Pivots low
//---------------------------------------------------//
if src1 > src1[rightbars] and lowest[rightbars](src1) > src1[rightbars] and src1[rightbars] < lowest[leftbars](src1)[rightbars+1] then
if $type[n]=1 then
$pivoty[n+1]=src1[rightbars]
$pivotx[n+1]=barindex[rightbars]
$type[n+1]=-1
n=n+1
else
$pivoty[n]=src1[rightbars]
$pivotx[n]=barindex[rightbars]
$type[n]=-1
endif
endif
//---------------------------------------------------//
//Pivots high
//---------------------------------------------------//
if src2 < src2[rightbars] and highest[rightbars](src2)<src2[rightbars] and src2[rightbars]>highest[leftbars](src2)[rightbars+1] then
if $type[n]=-1 then
$pivoty[n+1]=src2[rightbars]
$pivotx[n+1]=barindex[rightbars]
$type[n+1]=1
n=n+1
else
$pivoty[n]=src2[rightbars]
$pivotx[n]=barindex[rightbars]
$type[n]=1
endif
endif
//---------------------------------------------------//
//Average True Range Calculation
//---------------------------------------------------//
atr=averagetruerange[20](close)
//---------------------------------------------------//
//
//---------------------------------------------------//
if n>6 then
x1=$pivotx[n-5]
y1=$pivoty[n-5]
x2=$pivotx[n-4]
y2=$pivoty[n-4]
x3=$pivotx[n-3]
y3=$pivoty[n-3]
x4=$pivotx[n-2]
y4=$pivoty[n-2]
x5=$pivotx[n-1]
y5=$pivoty[n-1]
x6=$pivotx[n]
y6=$pivoty[n]
//y1-y3-y5 aprox en la misma horizontal
tolerance=tol/100
ymax=max(y1,max(y3,y5))
ymin=min(y1,min(y3,y5))
c1=100*(ymax/ymin-1)<=tol
//y2 menor que y1
c2=y2<y1
//y4 menor que y3
c3=y4<y3
//y6 menor que y5
c4=y6<y5
//y6 mayor que y4 e y4 mayor que y2
c5=y6>y4 and y4>y2
//Caida inicial
caida=round((y2/y1-1)*100,2)
setup = $type[n]=-1 and c1 and c2 and c3 and c4 and c5 and caida<-15
endif
//---------------------------------------------------//
// Cálculos en la última barra
//---------------------------------------------------//
if islastbarupdate then
for i=0 to barindex do
if setup[i] then
drawpoint(x1[i],y1[i],2)coloured("blue")
drawpoint(x2[i],y2[i],2)coloured("red")
drawpoint(x3[i],y3[i],2)coloured("blue")
drawpoint(x4[i],y4[i],2)coloured("red")
drawpoint(x5[i],y5[i],2)coloured("blue")
drawpoint(x6[i],y6[i],2)coloured("red")
drawrectangle(x1[i],y1[i],x5[i],y5[i])coloured("orange",0)fillcolor("orange",70)
drawsegment(x1[i],y1[i],x2[i],y2[i])coloured("darkred")style(dottedline3,2)
down=caida[i]
drawtext("#down# %",x2[i],y2[i]-atr[i])coloured("darkred")
drawsegment(x2[i],y2[i],x3[i],y3[i])coloured("darkblue")style(dottedline3,1)
drawsegment(x4[i],y4[i],x3[i],y3[i])coloured("darkred")style(dottedline3,1)
drawsegment(x4[i],y4[i],x5[i],y5[i])coloured("darkblue")style(dottedline3,1)
drawsegment(x6[i],y6[i],x5[i],y5[i])coloured("darkred")style(dottedline3,1)
break
endif
next
endif
//---------------------------------------------------//
return
.
