//Creating signals based on past divergences. Coding backwards. Check each new candle on the indicated setup.
//Building on the 5-min chart
//Max length of setup : 40 candles
//Version 22feb2019
RSIind = RSI[14](close)
//Find lowest low in RSI over the last NumberOfBars candles
RSILow1 = Lowest[NumberOfBars](RSIind)
IF RSILow1 < RSIBottom1 THEN
//reset all values
NoSignal = 0
NoSignalPart1 = 1
NoSignalPart2 = 1
NoSignalPart3 = 1
PriceLow1 = 0
PriceClose1 = 0
RSIBarindexLow1 = 0
PriceClose1NextBar = 0
GreenBarCondition = 0
BarindexDistanceToHigh = 0
MoveUpBarindex = 0
RSILow2 = 0
PriceLow2 = 0
GreenBarClose2Condition = 0
//Part 1
//find the barindex of the lowest RSI low, to also find the corresponding Price Low
//if RSI not below 29, stop calculating => No signal
FOR i=0 to NumberOfBars do
IF RSIind[i] = RSILow1 THEN
RSIBarindexLow1 = barindex[i]
PriceLow1 = low[i]
PriceClose1 = close[i]
IF i=0 then
//At this point cannot calc the close of next bar, so no signal yet
NoSignal = 1
ENDIF
IF NoSignal = 0 THEN
//Calc the Next bar close
PriceClose1NextBar = close[i-1]
//Addition : If low of this next bar is lower then PriceLow1 then update the low
IF low[i-1] < PriceLow1 THEN
PriceLow1 = low[i-1]
ENDIF
//Check if the candle following the 1st low is a green bar -> If not, no signal
GreenBarCondition = PriceClose1NextBar - PriceClose1
//If the next bar close is not 2 points higher then Close1 then no signal
if GreenBarCondition < MinGreenBar1 THEN
NoSignal = 1
endif
BREAK
ENDIF
ENDIF
//If condition is still valid, this section part is DONE
IF NoSignal = 0 THEN
NoSignalPart1 = 0
ENDIF
NEXT
//END Part 1
//Part 2 :Find the first Barindex after the RSILow where the distance is 20
BarindexDistanceTo1stLow = barindex - RSIBarindexLow1
if BarindexDistanceTo1stLow > 0 THEN
n = BarindexDistanceTo1stLow
Count = 0
Signal = 0
WHILE n <> 0 DO
IF High[n-1] - PriceLow1 > MaxUpAfterLow1 THEN
n = 0
Count = Count + 1
signal = 1
ELSE
n = n - 1
Count = Count +1
ENDIF
WEND
if signal = 1 THEN
MoveUpBarindex = RSIBarindexLow1 + Count
NoSignalPart2 = 0
ELSE
MoveUpBarindex = 0
NoSignalPart2 = 1
ENDIF
ENDIF
//END Part 2
//Part 3 : Find RSI2 low
IF NoSignal = 0 and MoveUpBarindex > 0 THEN
BarindexDistanceToHigh = barindex - MoveUpBarindex
IF BarindexDistanceToHigh > 0 THEN
RSILow2 = Lowest[BarindexDistanceToHigh](RSIind)
//Find barindex of the lowest 2nd RSI low
FOR l=0 to BarindexDistanceToHigh do
IF RSIind[l] = RSILow2 THEN
PriceLow2 = low[l]
IF l=0 then
//Cannot calc the close of next bar at this moment, so no signal yet
NoSignal = 1
ENDIF
IF NoSignal = 0 THEN
//Check if the candle following the low is a green one -> If not, no signal
GreenBarClose2Condition = close[l-1] - close[l]
if GreenBarClose2Condition < MinGreenBar2 THEN
NoSignal = 1
endif
ENDIF
BREAK
ENDIF
NEXT
//PriceLow2 must be 2 points lower then pricelow1
IF PriceLow1 - PriceLow2 < PriceLowerLow2 THEN
NoSignal = 1
ENDIF
//2nd RSI low must be at least 2 points higher then the first low, if not, no signal
IF RSILow2 - RSILow1 < RSIHigherLow2 THEN
NoSignal = 1
ENDIF
ELSE
NoSignal = 1
ENDIF
IF NoSignal = 0 THEN
NoSignalPart3 = 0
ENDIF
ENDIF
ELSE
NoSignal = 1
ENDIF
IF NoSignal = 0 and NoSignalPart1 = 0 and NoSignalPart2 = 0 and NoSignalPart3 = 0 THEN
Alarm = 1
ELSE
Alarm = 0
ENDIF
return Alarm as "Alarm"
.
