Questo è l’indicatore per vederle sul grafico dei prezzi, perché le strategie NON possono stampare niente:

t    = 255
s    = 15
c1   = (high[1] = high[2])    //Triangolo VERDE sulle due candele
c2   = (close < open)         //Triangolo ROSSO
Cond = c1 AND C2
IF Cond THEN
   HH = highest[4](high) + lowest[4](range)
   DrawText("▲",BarIndex[2],HH,Dialog,Bold,s) coloured("Green",t)
   DrawText("▲",BarIndex[1],HH,Dialog,Bold,s) coloured("Green",t)
   DrawText("▲",BarIndex,   HH,Dialog,Bold,s) coloured("Red",t)
ENDIF
RETURN

questa è la strategia:

c1   = (high[1] = high[2])    //Triangolo VERDE sulle due candele
c2   = (close < open)         //Triangolo ROSSO
Cond = c1 AND C2
IF Cond AND Not OnMarket THEN
   SELLSHORT 1 CONTRACT AT MARKET
   StopLoss    = high[1] + 2*PipSize
   TargetPrice = (close - abs(StopLoss - open))
   SET STOP   PRICE StopLoss
   SET TARGET PRICE TargetPrice
ENDIF
IF OnMarket AND Not OnMarket[1] THEN
   TargetPrice = (open - abs(StopLoss - open[1]))
   SET TARGET PRICE TargetPrice
ENDIF
graphonprice StopLoss    coloured("Red")
graphonprice TargetPrice coloured("Blue")

l’entrata viene fatta alla fine della candela C, quindi quando sta per aprirsi la successiva candela D, ma ancora non si sa quale sia il valore di apertura, quindi ho usato per la prima come probabile APERTURA della candela D il prezzo di CHIUSURA della candela C, mentre dalla successiva candela, conoscendo il prezzo d’APERTURA esatto ho usato questo (quindi cambiano leggermente i valori dalla seconda candela).

Ovviamente capitano segnali un pò “strani”, ad esempio dove la candela C è appena mezzo punto, quindi si hanno SL e TP minimi, ancora di più se pure le candele A e B non hanno massimi molto alti.

Quindi la candela C col triangolo rosso sopra non deve più esserci?

Questo è il nuovo indicatore:

t    = 255
s    = 15
c1   = (high = high[1])    //Triangolo VERDE sulle due candele
c2   = (close < open)
Cond = c1 AND C2
IF Cond THEN
   HH = highest[3](high) + lowest[3](range)
   DrawText("▲",BarIndex[1],HH,Dialog,Bold,s) coloured("Green",t)
   DrawText("▲",BarIndex   ,HH,Dialog,Bold,s) coloured("Green",t)
ENDIF
RETURN

e questa è la nuova strategia:

c1   = (high = high[1])    //Triangolo VERDE sulle due candele
c2   = (close < open)
Cond = c1 AND C2
IF Cond AND Not OnMarket THEN
   SELLSHORT 1 CONTRACT AT MARKET
   StopLoss    = high + 2*PipSize
   TargetPrice = (close - abs(StopLoss - open))
   SET STOP   PRICE StopLoss
   SET TARGET PRICE TargetPrice
ENDIF
IF OnMarket AND Not OnMarket[1] THEN
   TargetPrice = (open - abs(StopLoss - open[1]))
   SET TARGET PRICE TargetPrice
ENDIF
graphonprice StopLoss    coloured("Red")
graphonprice TargetPrice coloured("Blue")

allego una foto di come dovrebbe essere la nuova situazione grafica, se ho ben capito.

Quando hai scritto, nel primo post “Il target deve essere calcolato sottraendo la distanza tra l’open e lo stop dall’open stesso“, a quali OPEN ti riferisci, a quello ella Candela B o della Candela C (dove ci sono le freccette dell’entrata)?

Siccome avevano entrambe le stesse indicazioni testuali, non era molto chiaro, anche se lo immaginavo ho preferito chiedertelo per non rischiare di fare modifiche che avrebbero potuto non essere corrette.

Questa è la versione corretta:

c1   = (high = high[1])    //Triangolo VERDE sulle due candele
c2   = (close < open)
Cond = c1 AND C2
IF Cond AND Not OnMarket THEN
   SELLSHORT 1 CONTRACT AT MARKET
   StopLoss    = high + 2*PipSize
   TargetPrice = (close - abs(StopLoss - close))
   SET STOP   PRICE StopLoss
   SET TARGET PRICE TargetPrice
ENDIF
IF OnMarket AND Not OnMarket[1] THEN
   TargetPrice = open - abs(StopLoss - open)
   SET TARGET PRICE TargetPrice
ENDIF
graphonprice StopLoss    coloured("Red")
graphonprice TargetPrice coloured("Blue")